home *** CD-ROM | disk | FTP | other *** search
/ Softdisk Supreme / Softdisk Supreme.iso / pc / DSK Files / 0-49 / SD020b.dsk / SUPER-REM PLUS.bas < prev    next >
BASIC Source File  |  2003-06-12  |  11KB  |  114 lines
  1. 0  REM <CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H>       
  2. 1  REM <CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H>       
  3. 2  REM <CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H>       
  4. 5  REM <CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H>[][][][][][][][][][][][][][][][]<CTRL-M>[]                            []<CTRL-M>[]       SUPER-REM PLUS       []<CTRL-M>[]                            []<CTRL-M>[]             AND            []<CTRL-M>[]                            []
  5. 6  REM <CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H>[]         DATA-WRITE         []<CTRL-M>[]                            []<CTRL-M>[]         WRITTEN BY         []<CTRL-M>[]                            []<CTRL-M>[]          J.VARADY          []
  6. 7  REM <CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H>[]                            []<CTRL-M>[]        4 WOODMERE DR       []<CTRL-M>[]                            []<CTRL-M>[]        EATONTOWN NJ.       []<CTRL-M>[]                            []<CTRL-M>[]              07724         []
  7. 8  REM <CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H>[]                            []<CTRL-M>[][][][][][][][][][][][][][][][]
  8. 9  REM <CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H>       <CTRL-M><CTRL-M><CTRL-M><CTRL-D>VERIFY SUPER-REM PLUS
  9. 10  REM <CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H>--------------------------------<CTRL-M>            MAIN PROGRAM<CTRL-M>--------------------------------<CTRL-M><CTRL-M>
  10. 100  TEXT : HOME : PRINT  SPC( 120): LIST 63400,: FOR X = 1 TO 5000: NEXT : HOME : FOR X = 1 TO 39:N$ = N$ +"-": NEXT : PRINT N$: INVERSE : PRINT  SPC( 13);"SUPER-REM PLUS"; SPC( 12): NORMAL : PRINT : PRINT N$: POKE 34,3: POKE 35,22: VTAB 23: PRINT N$: VTAB 5
  11. 109  HOME : PRINT : PRINT 
  12. 110  GOSUB 62000
  13. 120  PRINT : HTAB 10: PRINT  CHR$(37);"..........CARRIAGE RETURN": PRINT : HTAB 10: PRINT  CHR$(64);"..........LEFT BRACKET-["
  14. 123  PRINT : PRINT 
  15. 124  HTAB 10: PRINT "FROM-------TO"
  16. 125 A$ = ""
  17. 130  GOSUB 60010: HOME : GOSUB 62000
  18. 140  PRINT : HTAB 10: PRINT "!..........BACKSPACE": PRINT : HTAB 10: PRINT  CHR$(34);"..........CARRIAGE RETURN": PRINT : HTAB 10: PRINT "#..........CONTROL-D": PRINT : HTAB 10: PRINT  CHR$(64);"..........LEFT-BRACKET-["
  19. 143  PRINT : PRINT 
  20. 144  HTAB 10: PRINT "FROM-------TO"
  21. 145 A$ = ""
  22. 150  GOSUB 60010: HOME : GOSUB 62000
  23. 160  HOME : VTAB 7: PRINT "PRESS 'B TO EXIT TO BASIC": PRINT : PRINT "ANYTHING ELSE TO REBOOT";: GET A$: IF A$ = "B"  THEN  TEXT : HOME : END 
  24. 170  PR# 6
  25. 39998  END 
  26. 39999  DATA &
  27. 40000  DATA  WELCOME TO SUPER-REM PLUS.  THIS PROGRAM AIDS THE USER IN THE CREATING OF OUTSTANDING REMARK STATEMENTS.
  28. 40010  DATA &,THE PROGRAM SEARCHES THRU ALL THE LINES IN THE PROGRAM FOR SPECIAL TOKENS IN REMARK AND PRINT STATEMENTS.
  29. 40020  DATA    UPON FINDING THESE TOKENS IT WILL CHANGE THEM TO OTHER VALUES.*
  30. 40030  DATA    &THESE ARE THE TOKENS THAT WILL BE CHANGED IN PRINT STATEMENTS-,XXX
  31. 40040  DATA &THESE ARE THE TOKENS THAT WILL BE CHANGED IN REMARK STATEMENTS-,XXX
  32. 40050  DATA &TO USE THE BACKSPACE IN REMARK STATEMENTS TO COVER OVER THE LINE NUMBER AND 'REM' PUT SIX !'S PLUS ONE FOR EVERY DIGIT IN THE LINE NUMBER.
  33. 40060  DATA *,&THE CARRIAGE RETURN WILL RETURN THE PRINTING CURSOR TO THE LEFT EDGE OF THE SCREEN.  YOU SHOULD NOT PUT MORE THAN 33 CHARACTERS ON A LINE OR THE APPLE WILL EDIT IT-PRODUCING UNDESIRABLE EFFECTS.
  34. 40070  DATA  *,&THE CONTROL-D WHEN PRECEDED BY A CARRIAGE RETURN WILL EXECUTE ANY DOS COMMAND FOLLOWING IT WHEN THE LINE IS LISTED.  THIS CAN BE USED FOR LIST PROTECTION AND MANY OTHER THINGS ...WELL USE YOUR IMMAGINATION.
  35. 40080  DATA *,&WHEN THE SUPER-REM PROGRAM IS RUN IT WILL ASK YOU FOR THE STARTING LINE.  THE FIRST LINE OF YOUR PROGRAM NO MATTER WHAT THE LINE NUMBER IS LINE #1.,*&WHILE THE PROGRAM IS RUNNING IT WILL PRINT A 'R' WHEN IT ENCOUNTERS A REM
  36. 40090  DATA STATEMENT.  IT WILL PRINT A 'P' WHEN IT ENCOUNTERS A PRINT STATEMENT AND IT WILL JUST PRINT A '.' WHEN NOTHING IS HAPPENING.
  37. 40100  DATA  *&THE NUMBER AFTER THE LINE NUMBER IS THE STARTING LOCATION OF THAT LINE.  THIS NUMBER, X AND X+1 ARE THE NUMBERS TO CHANGE (WITH A POKE X;NEW VALUE) THE LINE NUMBER.  CHANGE BOTH TO 255 FOR A LINE NUMBER OF 65535.
  38. 40110  DATA *&THE SUPER-REM PROGRAM STARTS AT LINE 63000.  TO USE IT ADD IT TO YOUR OWN PROGRAM USEING RENUMBER THEN 'RUN 63000'.
  39. 40120  DATA *&THE PROGRAM PRINTING OUT THIS PROGRAM IS CALLED DATA-WRITE.  IT DOES EXACTLY WHAT IT'S NAME IMPLIES - PRINTS THE CONTENTS OF DATA STATEMENTS AS YOU NOW SEE THEM.
  40. 40130  DATA *&THE PROGRAM IS NOT PERFECT AND CAN BE A REAL PAIN UNTILL YOU GET TO KNOW IT BUT IS EXTREMLY HELPFUL IN DOING PRESENTATIONS LIKE THIS.  &IT INDENTS NEW PARAGRAPHS AND WILL NOT CUT UP A WORD AT THE END OF THE LINE.
  41. 40140  DATA *&YOU MUST REALL TAKE A LOOK AT THE PROGRAM-IT STARTS AT LINE 62000.  THE PROGRAM IS STARTED BY A GOSUB 62000 AND WILL RETURN WHEN IN ENCOUNTERS A 'XXX' DATA ENTRY.
  42. 40150  DATA &AS I SAID IT IS NOT PERFECT AND YOU SHOULD CHANGE IT TO SUIT YOUR OWN NEEDS.
  43. 59998  DATA XXX
  44. 59999  END 
  45. 60000  REM <CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H>--------------------------------<CTRL-M>           ERROR-TRAP<CTRL-M><CTRL-M>   FROM:BEAGLE BROS TIP BOOK-5<CTRL-M>--------------------------------<CTRL-M>
  46. 60001 T = 256:E =  PEEK(220) +T * PEEK(221):E = E +5 *( PEEK(E) = 0):V =  PEEK(E): POKE E,207:L$ =  RIGHT$("0000" + STR$( PEEK(218) +T * PEEK(219)),5):L =  PEEK(121) +T * PEEK(122) +49: FOR I = 1 TO 5: POKE L +I, ASC( MID$ (L$,I,1)): NEXT : LIST 00000: POKE E,V: POKE 216,0: RESUME 
  47. 60002  REM <CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H>[][][][][][][][][][][][][][][][]<CTRL-M>[]  TO USE MAKE FIRST LINE    []<CTRL-M>[]     ON ERR GOTO 60001      []<CTRL-M>[][][][][][][][][][][][][][][][]
  48. 60009  REM <CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H>--------------------------------<CTRL-M>         PRESS ANY KEY<CTRL-M>--------------------------------
  49. 60010 VV = 24: POKE 34,21
  50. 60020  VTAB VV: HTAB 14: PRINT "PRESS        ": FOR F = 1 TO 250: NEXT : VTAB VV: HTAB 14: PRINT "PRESS ANY    ": FOR F = 1 TO 250: NEXT : VTAB VV: HTAB 14: PRINT "PRESS ANY KEY": FOR F = 1 TO 250: NEXT 
  51. 60022  VTAB VV: HTAB 14: PRINT "             ": FOR F = 1 TO 250: NEXT :Q =  PEEK( -16384)
  52. 60030  IF Q <128  THEN  GOTO 60020
  53. 60035 HO = 1
  54. 60040  POKE  -16368,0: POKE 34,3: VTAB 24: CALL  -868: VTAB 3: RETURN 
  55. 62000  REM <CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H>--------------------------------<CTRL-M>           DATA-WRITE<CTRL-M>--------------------------------<CTRL-M>
  56. 62001  REM <CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H>           <CTRL-M><<<<<<<<<< >>>>>>>>>><CTRL-M>&.....NEW PARAGRAPH<CTRL-M>*.....NEW PAGE<CTRL-M><<<<<<<<<< >>>>>>>>>><CTRL-M>
  57. 62009 HO = 1
  58. 62010 D = 2:SO =  -16336:PR$ = " "
  59. 62020  READ A1$: IF A1$ = "XXX"  THEN P$ = A$: GOSUB 62090: RETURN 
  60. 62030 A$ = A$ +" " +A1$
  61. 62040  IF  LEN(A$) <39  THEN  GOTO 62020
  62. 62050  GOSUB 62070: IF RE  THEN  RETURN 
  63. 62055  IF HO  THEN  VTAB 4:HO = 0
  64. 62060  GOTO 62040
  65. 62070  FOR X = 40 TO 0  STEP  -1: IF  MID$ (A$,X,1) = " "  THEN P$ =  LEFT$(A$,X):A$ =  RIGHT$(A$,( LEN(A$) -X)):X = 0
  66. 62080  NEXT 
  67. 62090  PRINT " ";
  68. 62096  IF HO  THEN  VTAB 4:HO = 0
  69. 62100  FOR X = 1 TO  LEN(P$):PP$ =  MID$ (P$,X,1)
  70. 62110  IF  ASC(PP$) = 38  THEN  PRINT  CHR$(8);" ":A$ = "    " + RIGHT$(P$,( LEN(P$) -X)) +A$:X =  LEN(P$): PRINT : RETURN 
  71. 62120  IF  ASC(PP$) = 42  THEN  PRINT  CHR$(8);" ": GOSUB 60010: HOME :A$ =  RIGHT$(P$,( LEN(P$) -X)) +A$:X =  LEN(P$):HO = 1: RETURN 
  72. 62130  PRINT  CHR$(8);PP$;: INVERSE : PRINT PR$;: NORMAL : FOR XX = 1 TO D:S =  PEEK(SO): NEXT : NEXT : PRINT  CHR$(8);" "
  73. 62140  IF  LEN(P$) <39  THEN  PRINT 
  74. 62150  RETURN 
  75. 63000  REM <CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H>--------------------------------<CTRL-M>         SUPER-REM PLUS<CTRL-M>--------------------------------
  76. 63001  REM <CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H>>>>>>>>>>>>>>>>><<<<<<<<<<<<<<<<<CTRL-M><CTRL-M>      -IN REM STATEMENTS-<CTRL-M>EXCLAIMATION PT.=BACKSPACE<CTRL-M>QUOTE=CARRIAGE RETURN<CTRL-M>NUMBER SIGN=CONTROL-D<CTRL-M>AT SIGN=LEFT BRACKET
  77. 63002  REM <CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H>           
  78. 63003  REM <CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H>      -IN PRINT STATEMENTS-<CTRL-M>PERCENT SIGN=CARRIAGE RETURN<CTRL-M>AT-SIGN=LEFT BRACKET<CTRL-M><CTRL-M><CTRL-M>ADD YOUR OWN AFTER LINE 63200<CTRL-M><CTRL-M>>>>>>>>>>>>>>>>><<<<<<<<<<<<<<<<<CTRL-M>
  79. 63010  TEXT : HOME :I = 1:L = 1
  80. 63020  LIST 63000: VTAB 24: PRINT : POKE 34,4: HOME 
  81. 63030  INPUT "RELATIVE STARTING LINE:";LI: IF LI <1  THEN  GOTO 63010
  82. 63040  HOME 
  83. 63050 SLOC =  PEEK(103) + PEEK(104) *256
  84. 63060 ELOC =  PEEK(175) + PEEK(176) *256
  85. 63070 LOC = SLOC +4: PRINT L;")";: HTAB 5: PRINT LOC -2;" ";:L = L +1: IF LI >1  THEN  GOTO 63090
  86. 63080  GOSUB 63200
  87. 63090 NLOC = (SLOC +( PEEK(SLOC) +1)): PRINT : PRINT L;")";: HTAB 5: PRINT NLOC;" ";:OLOC = NLOC:L = L +1: IF LI >2  THEN  GOTO 63110
  88. 63100  GOSUB 63190
  89. 63110  FOR X = 1 TO (LI -2): GOSUB 63160:OLOC = NLOC: IF NLOC > = ELOC  THEN  END 
  90. 63120  NEXT 
  91. 63130  GOSUB 63190
  92. 63140  GOSUB 63160: GOSUB 63190:OLOC = NLOC: IF NLOC > = ELOC  THEN  END 
  93. 63150  GOTO 63140
  94. 63160 NLOC = (SLOC +( PEEK(OLOC -2) +1))
  95. 63170 Q =  PEEK(NLOC -1) -8: IF Q = I  THEN SLOC = SLOC +256:I = I +1
  96. 63180  PRINT : PRINT L;")";: HTAB 5: PRINT NLOC;" ";:L = L +1: RETURN 
  97. 63190 LOC = (NLOC +2)
  98. 63200  IF  PEEK(LOC) = 186  THEN  GOTO 63240
  99. 63210  IF  PEEK(LOC) = 178  THEN  GOTO 63290
  100. 63220 LOC = LOC +1: IF  PEEK(LOC) = 0  THEN  RETURN 
  101. 63230  PRINT ".";: GOTO 63200
  102. 63240 LOC = LOC +1: PRINT "P";
  103. 63250  IF  PEEK(LOC) = 37  THEN  POKE LOC,13
  104. 63260  IF  PEEK(LOC) = 64  THEN  POKE LOC,91
  105. 63270  IF  PEEK(LOC) = 0  THEN  RETURN 
  106. 63280  GOTO 63240
  107. 63290 LOC = LOC +1: PRINT "R";
  108. 63300  IF  PEEK(LOC) = 33  THEN  POKE LOC,8
  109. 63310  IF  PEEK(LOC) = 34  THEN  POKE LOC,13
  110. 63320  IF  PEEK(LOC) = 35  THEN  POKE LOC,4
  111. 63325  IF  PEEK(LOC) = 64  THEN  POKE LOC,91
  112. 63330  IF  PEEK(LOC) = 0  THEN  RETURN 
  113. 63340  GOTO 63290
  114. 63736  REM <CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H>           <CTRL-M>---------------<CTRL-M>SUPER-REM PLUS<CTRL-M>VERSION 1.0<CTRL-M>MARCH 1983<CTRL-M><CTRL-M>  WRITTEN BY:<CTRL-M><CTRL-M>J.VARADY<CTRL-M>4 WOODMERE DR.<CTRL-M>EATONTOWN N.J.<CTRL-M>  07724<CTRL-M>---------------<CTRL-M>